【LookerStudio】着地見込みを追加する方法【コピペ可】

実績値は Looker Studio で GA4 や自社の DB を繋げばすぐ出る。急に面倒になるのは「着地見込み」のほうで、当月の経過日数と日数を使った計算が入る。目標に対して今月このまま行けるのかは、この1列があるかどうかで判断できるようになる。

今回はGA4（Google Analytics 4）の「キーイベント」の「日割り着地見込み」を出すための処理を記載していきます。この方法はGA4にかぎらず、Looker Studioのデータソースが日付データを持っていれば応用が効くので、SalesforceやHubSpotなどのリードの着地見込みを出すときにも使えますので、ぜひコピペして使ってみてください。

計算式

まず最初に「日割り着地見込み」の計算式を書いておきます。

SUM(今日までのキーイベント数) /当月経過日数 * 当月日数

シンプルに今日までのキーイベント数の合算値を経過日数で割って、当月の日数でかけ合わせたものが「日割り着地見込み」になると思います。

（例）今日2025/01/10時点での着地見込み

• キーイベント数：144 （9日までの累計）

当月経過日数：9 （前日まで）

当月日数：31

• 当月着地見込み数： 144/9*31=496

上記の計算式が実現できるような計算フィールドをそれぞれ作成していきます。

実装方法

当月経過日数

DATE_DIFF(
  CURRENT_DATE(),  
  PARSE_DATE('%Y-%m-%d', CONCAT(CAST(YEAR(CURRENT_DATE()) AS STRING), '-', CAST(MONTH(CURRENT_DATE()) AS STRING), '-01'))
)

このコードでは、当月の月初（1日）から今日（CURRENT_DATE()）までの日数を計算します。結果として「当月経過日数」が得られます。

例えば、今日が 2025-01-10 の場合：

• 月初：2025-01-01
• 今日：2025-01-10
• 差の日数：10 – 1 = 9 日

したがって、結果は「9」 になります。

当月日数

DATE_DIFF(
  PARSE_DATE('%Y-%m-%d',
    CONCAT(
      CAST(YEAR(CURRENT_DATE()) + IF(MONTH(CURRENT_DATE()) = 12, 1, 0) AS STRING),
      '-',
      IF(MONTH(CURRENT_DATE()) = 12, '01',  
        IF(MONTH(CURRENT_DATE()) + 1 < 10, CONCAT('0', CAST(MONTH(CURRENT_DATE()) + 1 AS STRING)), CAST(MONTH(CURRENT_DATE()) + 1 AS STRING))
      ),
      '-01'
    )
  ),
  PARSE_DATE('%Y-%m-%d',
    CONCAT(
      CAST(YEAR(CURRENT_DATE()) AS STRING),
      '-',
      IF(MONTH(CURRENT_DATE()) < 10, CONCAT('0', CAST(MONTH(CURRENT_DATE()) AS STRING)), CAST(MONTH(CURRENT_DATE()) AS STRING)),
      '-01'
    )
  )
)

「翌月1日-当月1日」を計算することで「当月日数」を出すことができます。lookerSTUDIOでは「DATE_TRUNC」関数や「LPAD」関数がサポートされていないため、かなり冗長な書き方になってしまいます。

例えば、今日が 2025-01-10 の場合：

• 次月の1日: 2025-02-01
• 当月の1日: 2025-01-01
• 差の日数: 31

したがって、結果は「31」 になります。

日割り着地見込み

{{keyEvents:xxx}} / 当月経過日数 * 当月日数

今回は「資料ダウンロード（downloads_finished）」で設定しているカスタム指標で出してみましたので下記のようになります。

keyEvents:downloads_finished / 当月経過日数 * 当月日数

{{keyEvents:xxx}} の部分は適宜着地を出したい指標に差し替えて算出することができます。この方法ですと実績の部分は計算したものをもってこれるので「資料ダウンロード＋セミナー参加＋問い合わせ」の着地をだしたり、様々な指標の着地見込みの算出ができます。

考慮できていないこと

• あくまで「当月着地見込み」なので、Looker Studioで日付を先月にしても計算が走ってしまいます。過去の実績などは別のデータでまとめたほうが見やすいと思います。
• ビジネスモデルによっては休日や祝日は係数をかけて日割り着地を算出しないと正確ではないということもありますが、関数上で表現が難しいので今回は「単純日割り」のみを記載しています。

まとめ

着地見込みがだせないから、スプレッドシートで集計をしている方がいましたら、こちらの記事を参考にLooker Studioへの移行をご検討ください！